إليك جهاز عرض صغير برأس متحرك وعملي. يعمل النظام بالكامل بفضل محركين سيرفو يتم التحكم فيهما بواسطة عصا تحكم، وبالنسبة للإضاءة، فهي عبارة عن مصباح LED RGB بسيط يغير لونه عبر زر عصا التحكم.

إذا كانت لديك أي أسئلة، لا تتردد في ترك تعليق، وسأرد عليك في أسرع وقت ممكن.

أعتقد أنني سأصدر فيديو تعليمياً قريباً (كما فعلت مع لوحة LED)، لذا لعدم فواته، تابعني من هنا 👉 https://www.youtube.com/@Tim_bricolage

إليك الفيديو التعليمي: https://youtu.be/61YztvEllS4

هذا يدعمني ويحفزني لإطلاق مشاريع أخرى.

للطباعة، يكفي ملء بنسبة 15%، وارتفاع طبقة 0.2. جميع النماذج تحتاج إلى دعامات.

المواد المطلوبة:

-2 طرف (صلبان بيضاء)

-2 مقاوم 100 أوم (للونين الأخضر والأزرق في المصباح)

-1 مقاوم 220 أوم (للون الأحمر في المصباح)

-1 مصباح LED RGB

-1 عصا تحكم

-2 محرك سيرفو

-1 لوحة تجارب أردوينو

-1 لوحة أردوينو (Mega 2560)

-أسلاك

للتوصيل:

هناك نوعان من مصابيح LED RGB، أحدهما بطرف أطول يجب توصيله بـ 5 فولت (مثل الخاص بي)، والنوع الثاني يجب توصيله بالأرضي GND. لذا تحقق من ذلك.

بمجرد الانتهاء من التوصيلات، ستكون النتيجة كالتالي:

WhatsApp Image 2025-08-12 à 12.37.05_f5e57dac.jpg

WhatsApp Image 2025-08-12 à 12.30.42_d131db1b.jpg

WhatsApp Image 2025-08-12 à 12.37.05_72823ac8.jpg

لبرنامج النسخ واللصق في Arduino IDE:

#include <Servo.h>

Servo servoBase;

Servo servoTilt;

const int joyXPin = A0;

const int joyYPin = A1;

const int joyBtnPin = 2;

const int ledR = 12;

const int ledG = 13;

const int ledB = 11;

float angleBase = 90;

float angleTilt = 90;

const int deadZone = 50;

const int fullPush = 250; // عصا التحكم يجب أن تتجاوز ±250 من المركز

const float maxSpeed = 3; // السرعة القصوى لمحركات السيرفو

const int colors[][3] = {

{255, 0, 0}, // أحمر

{0, 255, 0}, // أخضر

{0, 0, 255}, // أزرق

{255, 255, 0}, // أصفر

{0, 255, 255}, // سماوي

{255, 0, 255}, // أرجواني

{255, 255, 255} // أبيض

};

const int colorCount = sizeof(colors) / sizeof(colors[0]);

int currentColor = 0;

bool lastButtonState = HIGH;

bool baseActive = false;

bool tiltActive = false;

void setup() {

Serial.begin(9600);

pinMode(joyBtnPin, INPUT_PULLUP);

pinMode(ledR, OUTPUT);

pinMode(ledG, OUTPUT);

pinMode(ledB, OUTPUT);

updateLEDColor();

}

void loop() {

int joyX = analogRead(joyXPin);

int joyY = analogRead(joyYPin);

int offsetX = joyX - 512;

int offsetY = joyY - 512;

// --- سيرفو القاعدة (دوران يسار/يمين مع حد) ---

if (abs(offsetX) > fullPush) {

if (!baseActive) {

servoBase.attach(9);

baseActive = true;

}

float speedX = map(abs(offsetX), fullPush, 512, 0, maxSpeed);

if (offsetX < 0) speedX = -speedX;

angleBase += speedX;

angleBase = constrain(angleBase, 0, 180);

servoBase.write((int)angleBase);

} else if (baseActive) {

servoBase.detach();

baseActive = false;

}

// --- سيرفو الإمالة (أعلى/أسفل سلس) ---

if (abs(offsetY) > deadZone) {

if (!tiltActive) {

servoTilt.attach(10);

tiltActive = true;

}

float speedY = map(abs(offsetY), deadZone, 512, 0, maxSpeed);

if (offsetY < 0) speedY = -speedY;

angleTilt += speedY;

angleTilt = constrain(angleTilt, 0, 180);

servoTilt.write((int)angleTilt);

} else if (tiltActive) {

servoTilt.detach();

tiltActive = false;

}

// --- تغيير لون LED ---

bool btnState = digitalRead(joyBtnPin);

if (lastButtonState == HIGH && btnState == LOW) {

currentColor = (currentColor + 1) % colorCount;

updateLEDColor();

Serial.print("تم تغيير اللون: ");

Serial.println(currentColor);

delay(200);

}

lastButtonState = btnState;

delay(20);

}

void updateLEDColor() {

analogWrite(ledR, colors[currentColor][0]);

analogWrite(ledG, colors[currentColor][1]);

analogWrite(ledB, colors[currentColor][2]);

}

Servomotor