Ecco un mini proiettore a testa mobile funzionante. Il tutto funziona grazie a 2 servomotori controllati da un joystick e per la luce, c'è un semplice LED RGB che cambia colore tramite il pulsante del joystick.

Se avete domande non esitate a lasciare un commento, risponderò il più rapidamente possibile.

Penso di pubblicare un video tutorial a breve (come per il pannello LED), quindi per non perderne l'uscita, iscrivetevi qui 👉 https://www.youtube.com/@Tim_bricolage

Ecco il video tutorial: https://youtu.be/61YztvEllS4

Questo mi sostiene e mi dà più voglia di realizzare altri progetti.

Per la stampa, è sufficiente un riempimento del 15%, altezza del layer 0,2. Tutti i modelli richiedono supporti.

Materiale necessario:

-2 terminali (croci bianche)

-2 resistenze da 100 Ω (per il verde e il blu del LED)

-1 resistenza da 220 Ω (per il rosso del LED)

-1 LED RGB

-1 joystick

-2 servomotori

-1 breadboard Arduino

-1 scheda Arduino (Mega 2560)

-Dei cavi

Per il collegamento:

Esistono 2 tipi di LED RGB, uno con il terminale più lungo che deve essere collegato al 5V (come il mio) e il secondo tipo deve essere collegato al GND. Quindi verificate.

Una volta terminati i collegamenti, il risultato è questo:

WhatsApp Image 2025-08-12 à 12.37.05_f5e57dac.jpg

WhatsApp Image 2025-08-12 à 12.30.42_d131db1b.jpg

WhatsApp Image 2025-08-12 à 12.37.05_72823ac8.jpg

Per il programma da copiare e incollare nell'IDE di Arduino:

#include <Servo.h>

Servo servoBase;

Servo servoTilt;

const int joyXPin = A0;

const int joyYPin = A1;

const int joyBtnPin = 2;

const int ledR = 12;

const int ledG = 13;

const int ledB = 11;

float angleBase = 90;

float angleTilt = 90;

const int deadZone = 50;

const int fullPush = 250; // il joystick deve superare ±250 dal centro

const float maxSpeed = 3; // velocità max dei servomotori

const int colors[][3] = {

{255, 0, 0}, // Rosso

{0, 255, 0}, // Verde

{0, 0, 255}, // Blu

{255, 255, 0}, // Giallo

{0, 255, 255}, // Ciano

{255, 0, 255}, // Magenta

{255, 255, 255} // Bianco

};

const int colorCount = sizeof(colors) / sizeof(colors[0]);

int currentColor = 0;

bool lastButtonState = HIGH;

bool baseActive = false;

bool tiltActive = false;

void setup() {

Serial.begin(9600);

pinMode(joyBtnPin, INPUT_PULLUP);

pinMode(ledR, OUTPUT);

pinMode(ledG, OUTPUT);

pinMode(ledB, OUTPUT);

updateLEDColor();

}

void loop() {

int joyX = analogRead(joyXPin);

int joyY = analogRead(joyYPin);

int offsetX = joyX - 512;

int offsetY = joyY - 512;

// --- Servo Base (rotazione sinistra/destra con soglia) ---

if (abs(offsetX) > fullPush) {

if (!baseActive) {

servoBase.attach(9);

baseActive = true;

}

float speedX = map(abs(offsetX), fullPush, 512, 0, maxSpeed);

if (offsetX < 0) speedX = -speedX;

angleBase += speedX;

angleBase = constrain(angleBase, 0, 180);

servoBase.write((int)angleBase);

} else if (baseActive) {

servoBase.detach();

baseActive = false;

}

// --- Servo Tilt (su/giù fluido) ---

if (abs(offsetY) > deadZone) {

if (!tiltActive) {

servoTilt.attach(10);

tiltActive = true;

}

float speedY = map(abs(offsetY), deadZone, 512, 0, maxSpeed);

if (offsetY < 0) speedY = -speedY;

angleTilt += speedY;

angleTilt = constrain(angleTilt, 0, 180);

servoTilt.write((int)angleTilt);

} else if (tiltActive) {

servoTilt.detach();

tiltActive = false;

}

// --- Cambio colore LED ---

bool btnState = digitalRead(joyBtnPin);

if (lastButtonState == HIGH && btnState == LOW) {

currentColor = (currentColor + 1) % colorCount;

updateLEDColor();

Serial.print("Colore cambiato: ");

Serial.println(currentColor);

delay(200);

}

lastButtonState = btnState;

delay(20);

}

void updateLEDColor() {

analogWrite(ledR, colors[currentColor][0]);

analogWrite(ledG, colors[currentColor][1]);

analogWrite(ledB, colors[currentColor][2]);

}

projector