Aquí tienes un mini proyector con cabezal móvil totalmente funcional. Todo funciona mediante 2 servomotores controlados por un joystick y, para la luz, es un simple LED RGB que cambia de color gracias al botón del joystick.

Si tienes alguna pregunta, no dudes en dejar un comentario, te responderé lo más rápido posible.

Creo que pronto publicaré un video tutorial (como el del panel LED), así que para no perdértelo, pásate por aquí 👉 https://www.youtube.com/@Tim_bricolage

Aquí tienes el video tutorial: https://youtu.be/61YztvEllS4

Eso me apoya y me da más ganas de sacar adelante otros proyectos.

Para la impresión, con un 15% de relleno es suficiente, altura de capa de 0,2. Todos los modelos necesitan soportes.

Material necesario:

-2 puntas (cruces blancas)

-2 resistencias de 100 Ω (para el verde y azul del LED)

-1 resistencia de 220 Ω (para el rojo del LED)

-1 LED RGB

-1 joystick

-2 servomotores

-1 protoboard para Arduino

-1 placa Arduino (Mega 2560)

-Cables

Para las conexiones:

Existen 2 tipos de LED RGB, uno con la pata más larga que debe conectarse a 5V (como el mío) y el segundo tipo debe conectarse a GND. Así que compruébalo.

Una vez terminadas las conexiones, queda así:

WhatsApp Image 2025-08-12 à 12.37.05_f5e57dac.jpg

WhatsApp Image 2025-08-12 à 12.30.42_d131db1b.jpg

WhatsApp Image 2025-08-12 à 12.37.05_72823ac8.jpg

Para el programa a copiar y pegar en el IDE de Arduino:

#include <Servo.h>

Servo servoBase;

Servo servoTilt;

const int joyXPin = A0;

const int joyYPin = A1;

const int joyBtnPin = 2;

const int ledR = 12;

const int ledG = 13;

const int ledB = 11;

float angleBase = 90;

float angleTilt = 90;

const int deadZone = 50;

const int fullPush = 250; // el joystick debe superar ±250 del centro

const float maxSpeed = 3; // velocidad máxima de los servos

const int colors[][3] = {

{255, 0, 0}, // Rojo

{0, 255, 0}, // Verde

{0, 0, 255}, // Azul

{255, 255, 0}, // Amarillo

{0, 255, 255}, // Cian

{255, 0, 255}, // Magenta

{255, 255, 255} // Blanco

};

const int colorCount = sizeof(colors) / sizeof(colors[0]);

int currentColor = 0;

bool lastButtonState = HIGH;

bool baseActive = false;

bool tiltActive = false;

void setup() {

Serial.begin(9600);

pinMode(joyBtnPin, INPUT_PULLUP);

pinMode(ledR, OUTPUT);

pinMode(ledG, OUTPUT);

pinMode(ledB, OUTPUT);

updateLEDColor();

}

void loop() {

int joyX = analogRead(joyXPin);

int joyY = analogRead(joyYPin);

int offsetX = joyX - 512;

int offsetY = joyY - 512;

// --- Servo Base (rotación izquierda/derecha con umbral) ---

if (abs(offsetX) > fullPush) {

if (!baseActive) {

servoBase.attach(9);

baseActive = true;

}

float speedX = map(abs(offsetX), fullPush, 512, 0, maxSpeed);

if (offsetX < 0) speedX = -speedX;

angleBase += speedX;

angleBase = constrain(angleBase, 0, 180);

servoBase.write((int)angleBase);

} else if (baseActive) {

servoBase.detach();

baseActive = false;

}

// --- Servo Tilt (arriba/abajo fluido) ---

if (abs(offsetY) > deadZone) {

if (!tiltActive) {

servoTilt.attach(10);

tiltActive = true;

}

float speedY = map(abs(offsetY), deadZone, 512, 0, maxSpeed);

if (offsetY < 0) speedY = -speedY;

angleTilt += speedY;

angleTilt = constrain(angleTilt, 0, 180);

servoTilt.write((int)angleTilt);

} else if (tiltActive) {

servoTilt.detach();

tiltActive = false;

}

// --- Cambio de color del LED ---

bool btnState = digitalRead(joyBtnPin);

if (lastButtonState == HIGH && btnState == LOW) {

currentColor = (currentColor + 1) % colorCount;

updateLEDColor();

Serial.print("Color cambiado: ");

Serial.println(currentColor);

delay(200);

}

lastButtonState = btnState;

delay(20);

}

void updateLEDColor() {

analogWrite(ledR, colors[currentColor][0]);

analogWrite(ledG, colors[currentColor][1]);

analogWrite(ledB, colors[currentColor][2]);

}

lumière